# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# This is separate from build/config/BUILD.gn to avoid including various .gni
# that it requires, which in turn conflict with settings from BUILDCONFIG.gn
# when building in other trees.

import("./buildflag_header.gni")
import("./platform.gni")

config("mini_chromium_config") {
  include_dirs = [
    "..",
    root_gen_dir,
  ]
}

source_set("build") {
  sources = [ "build_config.h" ]
  public_configs = [ ":mini_chromium_config" ]
  public_deps = [ ":buildflag_header_h" ]
}

source_set("buildflag_header_h") {
  sources = [ "buildflag.h" ]
}

buildflag_header("chromeos_buildflags") {
  header = "chromeos_buildflags.h"
  header_dir = "build"

  flags = [
    "IS_CHROMEOS_LACROS=$mini_chromium_is_chromeos_lacros",
    "IS_CHROMEOS_ASH=$mini_chromium_is_chromeos_ash",
  ]
}
